[fdo-dev] FDO172 & Warning of "build breaker" changes

Jason Birch Jason.Birch at nanaimo.ca
Tue Sep 26 11:40:22 EDT 2006


This is the batch file that I've been using...

Jason 

-----Original Message-----
From: Greg Boone [mailto:greg.boone at autodesk.com] 
Sent: Tuesday, September 26, 2006 08:26
To: dev at fdo.osgeo.org
Subject: RE: [fdo-dev] FDO172 & Warning of "build breaker" changes

No. There is no update script yet. It is on my list of things to do....

-----Original Message-----
From: Mateusz Loskot [mailto:mateusz at loskot.net]
Sent: Tuesday, September 26, 2006 10:28 AM
To: dev at fdo.osgeo.org
Subject: Re: [fdo-dev] FDO172 & Warning of "build breaker" changes

Greg Boone wrote:
> Hi Frank,
> 
> I just did a checkout from fdocore.osgeo.org and fdogdal.osgeo.org and

> everything build successfully.
> 
> Did you run the checkoutsvn.bat script to synchronize all fdo osgeo 
> folders?


Greg,

Is there any new version of checkoutsvn.bat script?

Have you seen my comments I posted some time ago:

https://fdo.osgeo.org/servlets/ReadMsg?list=dev&msgNo=69

This script won't correctly *merge* new changes into local copy.

Cheers
--
Mateusz Loskot
http://mateusz.loskot.net

---------------------------------------------------------------------
To unsubscribe, e-mail: dev-unsubscribe at fdo.osgeo.org For additional
commands, e-mail: dev-help at fdo.osgeo.org



---------------------------------------------------------------------
To unsubscribe, e-mail: dev-unsubscribe at fdo.osgeo.org For additional
commands, e-mail: dev-help at fdo.osgeo.org

-------------- next part --------------
@echo off

SET DEFMODIFYCHK=no
SET FDOCOREENABLECHK=yes
SET THRPENABLECHK=yes
SET FDOENABLECHK=yes
SET UTILENABLECHK=yes
SET SHPENABLECHK=yes
SET SDFENABLECHK=yes
SET WFSENABLECHK=yes
SET WMSENABLECHK=yes
SET ARCENABLECHK=yes
SET RDBMSENABLECHK=yes
SET GDALENABLECHK=yes

if (%FDO_SVN_ROOT%)==() SET FDO_SVN_ROOT=%cd%

:study_params
if (%1)==() goto start_checkout

if "%1"=="-help"    goto help_show
if "%1"=="-h"       goto help_show

if "%1"=="-o"       goto get_path
if "%1"=="-outpath" goto get_path

if "%1"=="-u"       goto get_user
if "%1"=="-user"    goto get_user

if "%1"=="-p"         goto get_password
if "%1"=="-password"  goto get_password

if "%1"=="-w"       goto get_with
if "%1"=="-with"    goto get_with

goto custom_error

:get_password
if (%2)==() goto custom_error
SET FDO_SVN_PASSWORD=%2
goto next_param

:get_user
if (%2)==() goto custom_error
SET FDO_SVN_USERNAME=%2
goto next_param

:get_with
if "%DEFMODIFYCHK%"=="yes" goto stp0_get_with
	SET DEFMODIFYCHK=yes
	SET THRPENABLECHK=no
	SET FDOCOREENABLECHK=no
	SET FDOENABLECHK=no
	SET SHPENABLECHK=no
	SET SDFENABLECHK=no
	SET WFSENABLECHK=no
	SET WMSENABLECHK=no
	SET ARCENABLECHK=no
	SET RDBMSENABLECHK=no
	SET UTILENABLECHK=no
	SET GDALENABLECHK=no
:stp0_get_with
if not "%2"=="providers" goto stp1_get_with
	SET SHPENABLECHK=yes
	SET SDFENABLECHK=yes
	SET WFSENABLECHK=yes
	SET WMSENABLECHK=yes
	SET ARCENABLECHK=yes
	SET RDBMSENABLECHK=yes
	SET GDALENABLECHK=yes
	goto next_param
:stp1_get_with
if not "%2"=="all" goto stp2_get_with
	SET THRPENABLECHK=no
	SET FDOENABLECHK=no
	SET UTILENABLECHK=no
	SET FDOCOREENABLECHK=yes
	SET SHPENABLECHK=yes
	SET SDFENABLECHK=yes
	SET WFSENABLECHK=yes
	SET WMSENABLECHK=yes
	SET ARCENABLECHK=yes
	SET RDBMSENABLECHK=yes
	SET GDALENABLECHK=yes
	goto next_param
:stp2_get_with
if not "%2"=="fdocore" goto stp3_get_with
	SET FDOCOREENABLECHK=yes
	SET THRPENABLECHK=no
	SET FDOENABLECHK=no
	SET UTILENABLECHK=no
	goto next_param
:stp3_get_with
if not "%2"=="thirdparty" goto stp4_get_with
	SET THRPENABLECHK=yes
	goto next_param
:stp4_get_with
if not "%2"=="utilities" goto stp5_get_with
	SET UTILENABLECHK=yes
	goto next_param
:stp5_get_with
if not "%2"=="fdo" goto stp6_get_with
	SET FDOENABLECHK=yes
	goto next_param
:stp6_get_with
if not "%2"=="shp" goto stp7_get_with
	SET SHPENABLECHK=yes
	goto next_param
:stp7_get_with
if not "%2"=="sdf" goto stp8_get_with
	SET SDFENABLECHK=yes
	goto next_param
:stp8_get_with
if not "%2"=="wfs" goto stp9_get_with
	SET WFSENABLECHK=yes
	goto next_param
:stp9_get_with
if not "%2"=="wms" goto stp10_get_with
	SET WMSENABLECHK=yes	
	goto next_param
:stp10_get_with
if not "%2"=="arcsde" goto stp11_get_with
	SET ARCENABLECHK=yes	
	goto next_param
:stp11_get_with
if not "%2"=="rdbms" goto stp12_get_with
	SET RDBMSENABLECHK=yes
    goto next_param
:stp12_get_with
if not "%2"=="gdal" goto custom_error
	SET GDALENABLECHK=yes
    goto next_param

:get_path
if (%2)==() goto custom_error
if not exist "%~2" mkdir "%~2"
pushd "%~2"
if errorlevel 1 goto error
SET FDO_SVN_ROOT=%cd%
popd

:next_param
shift
shift
goto study_params

:start_checkout

if "%FDO_SVN_PASSWORD%"=="" goto custom_error
if "%FDO_SVN_USERNAME%"=="" goto custom_error

if not exist "%FDO_SVN_ROOT%" mkdir "%FDO_SVN_ROOT%"

if "%FDOCOREENABLECHK%"=="yes" goto checkout_all

:checkout_fdo
if "%FDOENABLECHK%"=="no" goto checkout_thirdparty
echo Updating Fdo
svn update https://fdocore.osgeo.org/svn/fdocore/trunk/Fdo "%FDO_SVN_ROOT%\Fdo" --username %FDO_SVN_USERNAME% --password %FDO_SVN_PASSWORD%
if errorlevel 1 goto error

:checkout_thirdparty
if "%THRPENABLECHK%"=="no" goto checkout_utilities
echo Updating ThirdParty
svn update https://fdocore.osgeo.org/svn/fdocore/trunk/Thirdparty "%FDO_SVN_ROOT%\Thirdparty" --username %FDO_SVN_USERNAME% --password %FDO_SVN_PASSWORD%
if errorlevel 1 goto error

:checkout_utilities
if "%UTILENABLECHK%"=="no" goto checkout_shp
echo Updating Utilities
svn update https://fdocore.osgeo.org/svn/fdocore/trunk/Utilities "%FDO_SVN_ROOT%\Utilities" --username %FDO_SVN_USERNAME% --password %FDO_SVN_PASSWORD%
if errorlevel 1 goto error
goto checkout_shp

:checkout_all
echo Updating FDO
svn update https://fdocore.osgeo.org/svn/fdocore/trunk/Fdo "%FDO_SVN_ROOT%\Fdo" --username %FDO_SVN_USERNAME% --password %FDO_SVN_PASSWORD%
if errorlevel 1 goto error
echo Updating www
svn update https://fdocore.osgeo.org/svn/fdocore/trunk/www "%FDO_SVN_ROOT%\www" --username %FDO_SVN_USERNAME% --password %FDO_SVN_PASSWORD%
if errorlevel 1 goto error
echo Updating ThirdParty
svn update https://fdocore.osgeo.org/svn/fdocore/trunk/Thirdparty "%FDO_SVN_ROOT%\Thirdparty" --username %FDO_SVN_USERNAME% --password %FDO_SVN_PASSWORD%
if errorlevel 1 goto error
echo Updating Utilities
svn update https://fdocore.osgeo.org/svn/fdocore/trunk/Utilities "%FDO_SVN_ROOT%\Utilities" --username %FDO_SVN_USERNAME% --password %FDO_SVN_PASSWORD%
if errorlevel 1 goto error
echo Updating Base
svn update https://fdocore.osgeo.org/svn/fdocore/trunk -N "%FDO_SVN_ROOT%" --username %FDO_SVN_USERNAME% --password %FDO_SVN_PASSWORD%
if errorlevel 1 goto error

:checkout_shp
if "%SHPENABLECHK%"=="no" goto checkout_sdf
echo Updating provider: SHP
svn update https://fdoshp.osgeo.org/svn/fdoshp/trunk/Providers/SHP "%FDO_SVN_ROOT%\Providers\SHP" --username %FDO_SVN_USERNAME% --password %FDO_SVN_PASSWORD%
if errorlevel 1 goto error

:checkout_sdf
if "%SDFENABLECHK%"=="no" goto checkout_wfs
echo Updating provider: SDF
svn update https://fdosdf.osgeo.org/svn/fdosdf/trunk/Providers/SDF "%FDO_SVN_ROOT%\Providers\SDF" --username %FDO_SVN_USERNAME% --password %FDO_SVN_PASSWORD%
if errorlevel 1 goto error

:checkout_wfs
if "%WFSENABLECHK%"=="no" goto checkout_wms
echo Updating provider: WFS
svn update https://fdowfs.osgeo.org/svn/fdowfs/trunk/Providers/WFS "%FDO_SVN_ROOT%\Providers\WFS" --username %FDO_SVN_USERNAME% --password %FDO_SVN_PASSWORD%
if errorlevel 1 goto error

:checkout_wms
if "%WMSENABLECHK%"=="no" goto checkout_arcsde
echo Updating provider: WMS
svn update https://fdowms.osgeo.org/svn/fdowms/trunk/Providers/WMS "%FDO_SVN_ROOT%\Providers\WMS" --username %FDO_SVN_USERNAME% --password %FDO_SVN_PASSWORD%
if errorlevel 1 goto error

:checkout_arcsde
if "%ARCENABLECHK%"=="no" goto checkout_generic
echo Updating provider: ArcSDE
svn update https://fdoarcsde.osgeo.org/svn/fdoarcsde/trunk/Providers/ArcSDE "%FDO_SVN_ROOT%\Providers\ArcSDE" --username %FDO_SVN_USERNAME% --password %FDO_SVN_PASSWORD%
if errorlevel 1 goto error

:checkout_generic
if "%RDBMSENABLECHK%"=="no" goto checkout_gdal
echo Updating provider: GenericRDBMS
svn update https://fdordbms.osgeo.org/svn/fdordbms/trunk/Providers/GenericRdbms "%FDO_SVN_ROOT%\Providers\GenericRdbms" --username %FDO_SVN_USERNAME% --password %FDO_SVN_PASSWORD%
if errorlevel 1 goto error

:checkout_gdal
if "%GDALENABLECHK%"=="no" goto end
echo Updating provider: GDAL
svn update https://fdogdal.osgeo.org/svn/fdogdal/trunk/Providers/GDAL "%FDO_SVN_ROOT%\Providers\GDAL" --username %FDO_SVN_USERNAME% --password %FDO_SVN_PASSWORD%
if errorlevel 1 goto error

:end

exit /B 0

:error
echo Failed to checkout files.
exit /B 1

:custom_error
echo The command is not recognized.
echo Please use the format:
:help_show
echo **************************************************************
echo checkoutsvn.bat [-h] 
echo                 [-o=OutFolder] 
echo                 [-w=WithModule] 
echo                 -u=UserId 
echo                 -p=UserPassword
echo *
echo Help:           -h[elp]
echo OutFolder:      -o[utpath]=destination folder for files
echo WithModule:     -w[ith]=all(default), 
echo                         fdo, 
echo                         fdocore, 
echo                         thirdparty, 
echo                         providers, 
echo                         utilities, 
echo                         shp, 
echo                         sdf, 
echo                         wfs, 
echo                         wms, 
echo                         arcsde, 
echo                         rdbms, 
echo                         gdal
echo User:           -u[ser]=user id
echo Password:       -p[assword]=user password
echo **************************************************************
exit /B 0


More information about the Fdo-internals mailing list